1 REM FROM COMPUTE 4/84 PAGE 167
2 REM ENTERED FOR CUON LIBRARY BY SAM BARRETT
10 PRINT"[147]MAKE BASIC LOADER OUT OF"
20 PRINT"DISK OBJECT FILE."
30 INPUT"ENTER FILENAME";FL$
40 OPEN 15,8,15
50 OPEN8,8,8,FL$+",P,R"
60 GOSUB 370
70 INPUT"FILENAME TO CREATE";FC$
80 OPEN9,8,9,"0:"+FC$+",P,W"
90 GOSUB 370
100 GET#8,LO$,HI$
110 PRINT#9,CHR$(1)+CHR$(4);
120 LINK$=CHR$(1)+CHR$(1)
130 PRINT#9,LINK$;
140 FOR I=1 TO 4:READ BYTE:PRINT#9,CHR$(BYTE);:NEXT I
150 PRINT#9,MID$(STR$(ASC(LO$+CHR$(0))+ASC(HI$+CHR$(0))*256),2);
160 FORI=1 TO 42:READ BYTE:PRINT#9,CHR$(BYTE);:NEXT I
170 DATA 10,0,73,178,0,31,4,20
180 DATA 0,135,32,65,58,139
190 DATA 32,65,178,50,53,54,32,167,32,128
200 DATA 0,52,4,30,0,151,32,73,44,65,58,73,178,73,170,49,58,137,32,50,48,0
210 LO=ASC(LO$+CHR$(0)):HI=ASC(HI$+CHR$(0))
220 PRINT#9,LINK$+CHR$(LO)+CHR$(HI);
230 PRINT#9,CHR$(131)CHR$(32);
240 COUNT=1
250 GET#8,BYTE$:S=ST
260 PRINT#9,MID$(STR$(ASC(BYTE$+CHR$(0))),2);
270 COUNT=COUNT+1
280 IF COUNT=9 OR S<>0 THEN 310
290 PRINT#9,",";
300 GOTO 250
310 IF S THEN 340
320 LO=LO+8:IF LO>255 THEN LO=LO-256:HI=HI+1
330 PRINT#9,CHR$(0);:GOTO220
340 PRINT#9,",256"+CHR$(0)+CHR$(0)+CHR$(0);
350 CLOSE8:CLOSE9:CLOSE15
360 END
370 INPUT#15,E1,E2$,E3,E4
380 IF E1=0 THEN RETURN
390 PRINT"ERROR - "E1;E2$;E3;E4
400 CLOSE8:CLOSE9:CLOSE15